'ProgramMode:RUN
"ERROR"Disps"The government of the district in which the company operating this game is not able to acess the running functions of their"Disps"products.As this happens,the system will display this message."Disps"Right now,the federal government is in main control of this page.They have decided not to run this app"Disps"Right now,the earliest  the system will be back up is on Sep19"
"EXE Gain acess"DispsRanInt#(1,100)->Theta
Theta=69=>Goto Theta
Theta=21=>Goto Theta
Stop
Lbl Theta
Goto V
Lbl X:ClrText
"SnakeVS"->List 5
Dim List 5<>3=>3->Dim List 5
"_#E6A4_"->Str 1:"_#E59B_"->Str 2
"_#E6A4__#E6A4__#E6A4__#E6A4__#E6A4_"->Str 3
Menu "Snake_#E694_Versus   _@E756__#E5D2_._#E5D1_","Classic  _#E6D3__#E6D3__#E6D3__#E6D3__#E6D3_ *",0,"Versus   _#E6A4__#E6A4__#E6A4__#E694__#E6A3__#E6A3__#E6A3_",A,"Scores",U,"Help & Contact",Y,"Reset",W,"Exit",Z
Lbl A
ClrText
Locate 1,2,"Bot Difficulty:"
Locate 1,4,"[_@E746__#E5D1_] Easy":Locate 1,5,"[_@E746__#E5D2_] Medium":Locate 1,6,"[_@E746__#E5D3_] Hard"
Do
Getkey
LpWhile Ans<>79 And Ans<>69 And Ans<>59
Ans=79=>0->Q
Ans=69=>1->Q
Ans=59=>2->Q
ClrText
If Q=2
Then "_#E6A3_"->Str 4
"_#E6A3__#E6A3__#E6A3__#E6A3__#E6A3_"->Str 5
"Mobbydick"->Str 6
IfEnd
If Q=1
Then "_#E6D3_"->Str 4
"_#E6D3__#E6D3__#E6D3__#E6D3__#E6D3_"->Str 5
"Knackyball"->Str 6
IfEnd
If Q=0
Then "_#E6A5_"->Str 4
"_#E6A5__#E6A5__#E6A5__#E6A5__#E6A5_"->Str 5
"Carryfish"->Str 6
IfEnd
Locate 9,2,Str 3
Locate 9,3,"Player"
Do:LpWhile Getkey
Getkey<>31
For 1->Theta To 9
Locate Theta,4," V"
Locate 21-Theta,4,"S "
Next
Locate 7,5,Str 6
Locate 9,6,Str 5
Locate 15,7," [_@E745__@E758__@E745_]"
Do
RanInt#(0,1->Theta
Theta=0=>Locate 11,4,"_#E694_"
Theta=1=>Locate 11,4,"_#E695_"
LpWhile Getkey<>31
ClrText
RanInt#(2,10->Theta:10Theta->M
Locate 7,4,"Goal:"
Locate 13,4,M
Locate 15,7," [_@E745__@E758__@E745_]"
For 1-><r> To 100:Next
0-><r>:Do
Getkey=0=>1-><r>
<r>=1 And Getkey=31=>2-><r>
LpWhile <r><>2
ClrText
Locate 1,1,"_#E6A4_         _#E695_"
Locate 21,1,Str 4
For 2->Theta To 7
Locate 11,Theta,"|"
Next
{7,21->Dim Mat A
2->Mat A[2,1]
2->Mat A[2,2]
2->Mat A[2,3]
2->Mat A[2,4]
4->X:2->Y:1->V:2->W:2-><r>
4->Mat A[2,21]
4->Mat A[2,20]
4->Mat A[2,19]
4->Mat A[2,18]
18->A:2->B:21->C:2->D:4->Theta:-10->R:-10->S
Goto C
Lbl B
S=M Or R=M=>Goto H
Getkey<>G And Getkey<>0=>Getkey->G
G=28 And <r><>3=>1-><r>
G=27 And <r><>4=>2-><r>
G=37 And <r><>1=>3-><r>
G=38 And <r><>2=>4-><r>
G=48=>Goto E
<r>->Mat A[Y,X]
<r>=1=>Dsz Y
<r>=2=>Isz X
<r>=3=>Isz Y
<r>=4=>Dsz X
X=11=>1->X
X=0=>10->X
Y=1=>7->Y
Y=8=>2->Y
Locate X,Y,Str 1
Mat A[W,V]
0->Mat A[W,V]
Mat A[Y,X]<>0=>Goto F
Ans=0=>Goto F
Ans=1=>Dsz W
Ans=2=>Isz V
Ans=3=>Isz W
Ans=4=>Dsz V
V=11=>1->V
V=0=>10->V
W=1=>7->W
W=8=>2->W
X=V And Y=W=>Goto F
Locate V,W," "
A>E And Theta<>2=>4->Theta
A<E And Theta<>4=>2->Theta
B>F And Theta<>3=>1->Theta
B<F And Theta<>1=>3->Theta
Getkey<>G And Getkey<>0=>Getkey->G
If Q=1
Then A<>21=>Mat A[B,A+1]<>0 And Theta=2=>3->Theta
A<>12=>Mat A[B,A-1]<>0 And Theta=4=>1->Theta
B<>7=>Mat A[B+1,A]<>0 And Theta=3=>2->Theta
B<>2=>Mat A[B-1,A]<>0 And Theta=1=>4->Theta
IfEnd
If Q=2
Then Theta=2=>A<>21 And B<>2=>Mat A[B,A+1]<>0=>Mat A[B-1,A]<>0=>3->Theta
Theta=2=>A<>21 And B<>7=>Mat A[B,A+1]<>0=>Mat A[B+1,A]<>0=>1->Theta
Theta=2=>A<>21 And B<>2 And B<>7=>Mat A[B,A+1]<>0=>Mat A[B+1,A]=0 And Mat A[B-1,A]=0=>3->Theta
Theta=3=>B<>7 And A<>21=>Mat A[B+1,A]<>0=>Mat A[B,A+1]<>0=>4->Theta
Theta=3=>B<>7 And A<>12=>Mat A[B+1,A]<>0=>Mat A[B,A-1]<>0=>2->Theta
Theta=3=>B<>7 And A<>21 And A<>12=>Mat A[B+1,A]<>0=>Mat A[B,A+1]=0 And Mat A[B,A-1]=0=>4->Theta
Theta=4=>A<>12 And B<>2=>Mat A[B,A-1]<>0=>Mat A[B-1,A]<>0=>3->Theta
Theta=4=>A<>12 And B<>7=>Mat A[B,A-1]<>0=>Mat A[B+1,A]<>0=>1->Theta
Theta=4=>A<>12 And B<>2 And B<>7=>Mat A[B,A-1]<>0=>Mat A[B-1,A]=0 And Mat A[B+1,A]=0=>3->Theta
Theta=1=>B<>2 And A<>21=>Mat A[B-1,A]<>0=>Mat A[B,A+1]<>0=>4->Theta
Theta=1=>B<>2 And A<>12=>Mat A[B-1,A]<>0=>Mat A[B,A-1]<>0=>2->Theta
Theta=1=>B<>2 And A<>21 And A<>12=>Mat A[B-1,A]<>0=>Mat A[B,A+1]=0 And Mat A[B,A-1]=0=>4->Theta
IfEnd
Getkey<>G And Getkey<>0=>Getkey->G
Theta->Mat A[B,A]
Theta=1=>Dsz B
Theta=2=>Isz A
Theta=3=>Isz B
Theta=4=>Dsz A
A=22=>12->A
A=11=>21->A
B=1=>7->B
B=8=>2->B
Locate A,B,Str 4
Mat A[D,C]
0->Mat A[D,C]
Mat A[B,A]<>0=>Goto G
Ans=0=>Goto G
Ans=1=>Dsz D
Ans=2=>Isz C
Ans=3=>Isz D
Ans=4=>Dsz C
C=22=>12->C
C=11=>21->C
D=1=>7->D
D=8=>2->D
A=C And B=D=>Goto G
Locate C,D," "
X=T And Y=U=>Goto C
A=E And B=F=>Goto D
V=T And W=U=>Locate T,U,Str 2
Goto B
Lbl C
RanInt#(1,10->T
RanInt#(2,7->U
Mat A[U,T]<>0=>Goto C
S+10->S
Locate T,U,Str 2
Locate 3,1,S
Mat A[W,V]
Ans=1=>Isz W
Ans=2=>Dsz V
Ans=3=>Dsz W
Ans=4=>Isz V
V=11=>1->V
V=0=>10->V
W=1=>7->W
W=8=>2->W
Ans->Mat A[W,V]
S=0 And R=-10=>Goto D
Goto B
Lbl D
RanInt#(12,21->E
RanInt#(2,7->F
Mat A[F,E]<>0=>Goto D
R+10->R
Locate E,F,Str 2
Locate 17,1,R
Mat A[D,C]
Ans=1=>Isz D
Ans=2=>Dsz C
Ans=3=>Dsz D
Ans=4=>Isz C
C=22=>12->C
C=11=>21->C
D=1=>7->D
D=8=>2->D
Ans->Mat A[D,C]
Goto B
Lbl E
Menu "Pause","_#E69B_ Back to Game",B,"_#E690_ Restart Game",A,"_#E69C_ Menu",X,"_*_ Exit",Z
Lbl F
For 2->Y To 7
Locate 1,Y,"          "
For 1->X To 10
0->Mat A[Y,X]
Next:Next
2->Mat A[2,1]
2->Mat A[2,2]
2->Mat A[2,3]
2->Mat A[2,4]
4->X:2->Y:1->V:2->W:2-><r>
-10->S
Locate 3,1,"   "
Goto C
Lbl G
For 2->B To 7
Locate 12,B,"          "
For 12->A To 21
0->Mat A[B,A]
Next:Next
4->Mat A[2,21]
4->Mat A[2,20]
4->Mat A[2,19]
4->Mat A[2,18]
18->A:2->B:21->C:2->D:4->Theta:-10->R
Locate 17,1,"   "
Goto D
Lbl H
S=M=>X->A
S=M=>Y->B
For 1->X To 10 Step 0.1
Frac X=0=>Locate A,B," "
Frac X<>0=>Locate A,B,"!"
Next
For 2->Y To 7
Locate 1,Y,"          "
Locate 12,Y,"          "
Next
S=M=>3->X
R=M=>15->X
S=M=>15->Y
R=M=>3->Y
S=M=>List 5[2]+1->List 5[2]
R=M=>List 5[3]+1->List 5[3]
Locate 3,4,"Player"
Locate Y,5,"Sucks."
Locate 13,4,Str 6
Locate X,5,"Wins!"
Do:LpWhile Getkey<>31
Goto X
Lbl 0
ClrText
Locate 1,2,"Speed:"
Locate 1,4,"[_@E746__#E5D1_] Slower":Locate 1,5,"[_@E746__#E5D2_] Slow":Locate 1,6,"[_@E746__#E5D3_] Fast":Locate 1,7,"[_@E746__#E5D4_] Faster"
Do
Getkey
LpWhile Ans<>79 And Ans<>69 And Ans<>59 And Ans<>49
ClrText
Locate 1,1,"_@E753__@E743__@E74F__@E752__@E745_        _@E74C__@E745__@E756__@E745__@E74C_ 1"
Ans=79=>100->O
Ans=69=>50->O
Ans=59=>25->O
Ans=49=>0->O
{7,21->Dim Mat A
2->Mat A[2,1]
2->Mat A[2,2]
2->Mat A[2,3]
2->Mat A[2,4]
4->X:2->Y:1->V:2->W:2-><r>:-10->S
1->L
10->N
0->G
Goto 2
Lbl 1
Getkey<>G And Getkey<>0=>Getkey->G
G=28 And <r><>3=>1-><r>
G=27 And <r><>4=>2-><r>
G=37 And <r><>1=>3-><r>
G=38 And <r><>2=>4-><r>
G=48=>Goto 3
<r>->Mat A[Y,X]
<r>=1=>Dsz Y
<r>=2=>Isz X
<r>=3=>Isz Y
<r>=4=>Dsz X
X=22=>1->X
X=0=>21->X
Y=1=>7->Y
Y=8=>2->Y
Locate X,Y,Str 1
Mat A[Y,X]<>0=>Goto 4
Getkey<>G And Getkey<>0=>Getkey->G
Mat A[W,V]
0->Mat A[W,V]
Ans=0=>Goto 4
Ans=1=>Dsz W
Ans=2=>Isz V
Ans=3=>Isz W
Ans=4=>Dsz V
V=22=>1->V
V=0=>21->V
W=1=>7->W
W=8=>2->W
Locate V,W," "
X=T And Y=U=>Goto 2
V=T And W=U=>Locate T,U,Str 2
0->K:For 0->K To O
Next
Goto 1
Lbl 2
RanInt#(1,21->T
RanInt#(2,7->U
Mat A[U,T]<>0=>Goto 2
S+N->S
If S=50 Or S=100 Or S=200 Or S=500 Or S=1000
Then Isz L
S=50=>"_#E6D3_"->Str 1
S=100=>"_#E6A3_"->Str 1
S=200=>"_#E6A5_"->Str 1
S=500=>"_#E6A9_"->Str 1
S=1000=>"_#E6A6_"->Str 1

S=200=>"*"->Str 2
S=200=>20->N
S=500=>"_#E6A0_"->Str 2
S=500=>50->N
Locate 19,1,L
IfEnd
Locate T,U,Str 2
Locate 7,1,S
Mat A[W,V]
Ans=0=>Goto 4
Ans=1=>Isz W
Ans=2=>Dsz V
Ans=3=>Dsz W
Ans=4=>Isz V
V=22=>1->V
V=0=>21->V
W=1=>7->W
W=8=>2->W
Ans->Mat A[W,V]
Goto 1
Lbl 3
Menu "Pause","_#E69B_ Back to Game",1,"_#E690_ Restart Game",0,"_#E69C_ Menu",X,"_*_ Exit",Z
Lbl 4
Locate X,Y,"!"
For 1->X To 400:Next
List 5[1]-><r>
ClrText
S><r>=>S->List 5[1]
S<=<r>=>Locate 9,3,"Score"
S><r>=>Locate 4,3,"New Best Score!"
Locate 10,4,S
S=0=>Locate 7,4,"You Suck!"
15-><r>:Do
<r>+0.02-><r>
Frac <r>=0.4=>Locate 6,5,"_(-)_Game Over_(-)_"
Frac <r>=0=>Locate 6,5,"_-_         _-_"
LpWhile Getkey<>31
Goto X
Lbl Y
"Help:"
""
"In Classic, you play alone and try to     eat as many spiders  as possible."DispsClrText
"In Versus, you play  with a bot and the   first to reach the   Goal wins."DispsClrText
"Controls:"
""
"_#E692_,_#E691_,_#E693_,_#E690_: Move"
"Menu: Pause"
"F1,F2,F3,F4: Select  options"DispsClrText
"If you encounter a   bug and you are good at coding, please tryto fix it by yourselfsince i_#E596_m lazy and   stuff."DispsClrText
"If you achieve fixingthe bugs, contact me,"Disps"I would be happy to  have a beer and a    conversation with    you."DispsClrText
"Have a good game,"
""
"Eole, a lazy casio   programmer"
"@e_ol_e"
"iyry2me@gmail.com"DispsGoto X
Lbl W
ClrText
Locate 1,2,"Reset? All your"
Locate 1,3,"scores will be lost."
Locate 1,5,"[_@E746__#E5D1_] Yes"
Locate 1,6,"[_@E746__#E5D2_] No"
Do
Getkey
LpWhile Ans<>79 And Ans<>69
Ans=69=>Goto X
ClrText
ClrMat A
ClrList5
0->A~Z
Goto X
Lbl V
For 1->X To 200:Next
For 1->X To 6
Locate X,4,"Snake "
X<>1=>Locate X-1,4," "
Next
For 21->X To 12 Step -1
Locate X,4,"Versus "
Next
0-><r>:Do
<r>+0.05-><r>
RanInt#(0,1->X
X=0=>Locate 11,4,"_#E694_"
X=1=>Locate 11,4,"_#E695_"
Frac <r>=0.4=>Locate 9,5,"_(-)__@E745__@E758__@E745__(-)_"
Frac <r>=0=>Locate 9,5,"_-_   _-_"
LpWhile Getkey<>31
Goto X
Lbl U
Locate 1,1,"_@E749__@E74E_ _@E743__@E74C__@E741__@E753__@E753__@E749__@E743_:_-__-__-__-__-__-__-__-__-__-_"
Locate 1,2,"Best Score _(-)_"
Locate 14,2,List 5[1]
Locate 1,4,"_@E749__@E74E_ _@E756__@E745__@E752__@E753__@E755__@E753_:_-__-__-__-__-__-__-__-__-__-__-_"
Locate 1,5,"Victories _(-)_"
Locate 1,6,"Defeats   _(-)_"
Locate 13,5,List 5[2]
Locate 13,6,List 5[3]
Locate 15,7,"[_@E74D__@E745__@E74E__@E755_]"
Do
LpWhile Getkey<>48
Goto X
Lbl Z
ClrText
Stop